Question

我正在寻找一个逻辑（不是附加模块）来按这种格式排序。我有一个字符串列表，如下所示：

asdadasBBBsfasdasdas-0112
asdanfnfnfnfnf222ads-1210

等。我不能按数字排序，因为，例如：812＆gt; 113（812 = 2012年8月，113 = 2013年1月，所以不正确）

任何好的策略？

感谢，

Answer 1

Schwartzian transform：

怎么样？

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dump qw(dump);

my @list = (
    'asdadasBBBsfasdasdas-0112',
    'asdanfnfnfnfnf222ads-1210',
    'asdanfnfnfnfnf222ads-1211',
    'asdanfnfnfnfnf222ads-1010',
    'asdanfnfnfnfnf222ads-1011',
);

my @sorted = 
    map  { $_->[0] }
    sort { $a->[1] <=> $b->[1] or $a->[2] <=> $b->[2] }
    map  { /-(\d\d)(\d\d)$/; [$_, $2, $1] } @list;
dump @sorted;

<强>输出：

(
  "asdanfnfnfnfnf222ads-1010",
  "asdanfnfnfnfnf222ads-1210",
  "asdanfnfnfnfnf222ads-1011",
  "asdanfnfnfnfnf222ads-1211",
  "asdadasBBBsfasdasdas-0112",
)

Answer 2

schwartzian变换在这里将是一个巨大的浪费。这个类似的结构我的名字永远不会记得会更好。

my @sorted =
   map substr($_, 4),
    sort
     map substr($_, -2) . substr($_, -4, 2) . $_,
      @unsorted;

使用匹配运算符代替substr：

my @sorted =
   map substr($_, 4),
    sort
     map { /(..)(..)\z/s; $2.$1.$_ }
      @unsorted;

Answer 3

使用首先查看年份的排序函数，然后是日期：

sub mmyy_sorter {

    my $a_yy = substr($a, -2);
    my $b_yy = substr($b, -2);

    my $a_mm = substr($a, -4, 2);
    my $b_mm = substr($b, -4, 2);

    return ($a_yy cmp $b_yy) || ($a_mm cmp $b_mm);
}

my @sorted = sort mmyy_sorter @myarray;

注意：这在技术上效率不高，因为它必须为每次比较重新计算月份和年份子字段，而不是仅为阵列中的每个项目计算一次。

也可以利用Perl的自动类型转换，并使用<=>运算符代替cmp，因为所有值实际上都代表数字。

Answer 4

怎么样重拍几个月？例如：

812 = 12 * 12 + 8

113 = 13 * 12 + 1

你可以将岁月变成几个月，这将是好事。要选择数字，您可以使用正则表达式。

Answer 5

感谢@ M42的样本数据。

use strict;
use warnings;
use feature 'say';

my @list = (
    'asdadasBBBsfasdasdas-0112',
    'asdanfnfnfnfnf222ads-1210',
    'asdanfnfnfnfnf222ads-1211',
    'asdanfnfnfnfnf222ads-1010',
    'asdanfnfnfnfnf222ads-1011',
);

my @sorted = sort {
  my ($aa, $bb) = map { /(..)(..)\z/ and $2.$1 } $a, $b;
  $aa <=> $bb;
} @list;

say for @sorted;

<强>输出

asdanfnfnfnfnf222ads-1010
asdanfnfnfnfnf222ads-1210
asdanfnfnfnfnf222ads-1011
asdanfnfnfnfnf222ads-1211
asdadasBBBsfasdasdas-0112

按mmyy排序（月和年）

5 个答案: