Google Data Studio表：划分具有2个不同年份的数据

Question

我需要生成一个包含Quotes win％的表。公式为#won除以#sent。 我的问题是，有些报价会在一年之内赢得，但会在不同的年份发送。

（我的数据来自BigQuery）

数据如下：

Sale    Sent    Won
sale1   2019    2020
sale2   2019    2020
sale3   2016    2017
sale4   2017    2019
sale5   2020    2020
sale6   2020    2020
sale7   2018    2018
sale8   2016    2016
sale9   2015    2016
sale10  2016    2017
sale11  2016    2018
sale12  2018    2019

我希望能够在Data Studio中创建一个表，如下所示：

Year   SENT    WON  WIN%
2016     4     2    50%
2017     1     2    200%
2018     2     2    100%
2019     2     2    100%
2020     2     4    200%

我很想看看在Google Data Studio中是否有可能。任何建议都将受到高度赞赏。

Answer 1

添加了一个Google Data Studio Report进行演示，以及一个显示以下过程的GIF。

一种方法是在数据集处重构数据，并在Calculated Fields中使用Table：

1）数据转换
需要从当前的Wide structure to a Long data structure转换数据。在Google表格中可以实现此效果的一种方法是使用以下公式（Sheet1代表输入表；请参阅嵌入式Google表格进行澄清）：

=ArrayFormula(QUERY({
{Sheet1!A:A,IF(LEN(Sheet1!A:A),"Sent",""),Sheet1!B:B};
{Sheet1!A:A,IF(LEN(Sheet1!A:A),"Won",""),Sheet1!C:C}
},"Select * Where Col3 is not null Label Col2 'Dimension', Col3 'Year'",1))

2）表
- 维度 ：Year
- 排序 ：Year升序
- 指标 ：在下面添加3个计算字段：

3）计算字段
以下公式创建了上表中使用的度量标准（公式3.1和3.2需要在数据源级别中添加，而3.3可以是在图表级别中添加（如果需要）：

3.1）已发送

COUNT(CASE
   WHEN REGEXP_MATCH(Dimension, "Sent") THEN Year
   ELSE NULL END)

3.2）赢得

COUNT(CASE
   WHEN REGEXP_MATCH(Dimension, "Won") THEN Year
   ELSE NULL END)

3.3）WIN％

WON / SENT